[coreboot] [commit] r6444 - in trunk/src/mainboard/lenovo/x60: . acpi

[repository service]

Author: svens
Date: Mon Mar 14 14:42:08 2011
New Revision: 6444
URL: https://tracker.coreboot.org/trac/coreboot/changeset/6444

Log:
X60: Add _PRW/_PSW methods to LID/SLPB objects

This patch adds the required methods for enabling/disabling
the LID and SLPB objects as wake source. On Thinkpads, the
Fn key can (and is by the Vendor BIOS) programmed as Wake source,
so let's do it the same way.

Signed-off-by: Sven Schnelle 
Acked-by: Peter Stuge

Added:
   trunk/src/mainboard/lenovo/x60/acpi/systemstatus.asl
Modified:
   trunk/src/mainboard/lenovo/x60/acpi/lid.asl
   trunk/src/mainboard/lenovo/x60/acpi/sleepbutton.asl
   trunk/src/mainboard/lenovo/x60/dsdt.asl

Modified: trunk/src/mainboard/lenovo/x60/acpi/lid.asl
==============================================================================
--- trunk/src/mainboard/lenovo/x60/acpi/lid.asl	Mon Mar 14 10:08:27 2011	(r6443)
+++ trunk/src/mainboard/lenovo/x60/acpi/lid.asl	Mon Mar 14 14:42:08 2011	(r6444)
@@ -21,9 +21,12 @@

Field(ERAM, ByteAcc, NoLock, Preserve)
 {
+                Offset (0x32),
+			    , 2,
+			WKLD, 1,
    	Offset (0x46),
-				, 2,
-			LIDS	, 1
+			    , 2,
+			LIDS, 1
 }

Device(LID)
@@ -34,4 +37,18 @@
    {
    	return (LIDS)
    }
+
+	Method(_PRW, 0, NotSerialized)
+	{
+		Return (Package() { 0x18, 0x03 })
+	}
+
+	Method(_PSW, 1, NotSerialized)
+	{
+		if (Arg0) {
+			Store(1, WKLD)
+		} else {
+			Store(0, WKLD)
+		}
+	}
 }

Modified: trunk/src/mainboard/lenovo/x60/acpi/sleepbutton.asl
==============================================================================
--- trunk/src/mainboard/lenovo/x60/acpi/sleepbutton.asl	Mon Mar 14 10:08:27 2011	(r6443)
+++ trunk/src/mainboard/lenovo/x60/acpi/sleepbutton.asl	Mon Mar 14 14:42:08 2011	(r6444)
@@ -19,7 +19,31 @@
  * MA 02110-1301 USA
  */

+Field(ERAM, ByteAcc, NoLock, Preserve)
+{
+		Offset (0x32),
+			    , 4,
+			WKFN, 1,
+		Offset(0x83),
+			FNKY, 8
+}
+
 Device(SLPB)
 {
         Name (_HID, EisaId ("PNP0C0E"))
+	Method(_PRW, 0, NotSerialized)
+	{
+		Return (Package() { 0x18, 0x03 })
+	}
+
+	Method(_PSW, 1, NotSerialized)
+	{
+		if (Arg0) {
+			Store(6, FNKY) /* Fn key acts as wake button */
+			Store(1, WKFN)
+		} else {
+			Store(0, FNKY) /* Fn key normal operation */
+			Store(0, WKFN)
+		}
+	}
 }

Added: trunk/src/mainboard/lenovo/x60/acpi/systemstatus.asl
==============================================================================
--- /dev/null	00:00:00 1970	(empty, because file is newly added)
+++ trunk/src/mainboard/lenovo/x60/acpi/systemstatus.asl	Mon Mar 14 14:42:08 2011	(r6444)
@@ -0,0 +1,66 @@
+/*
+ * This file is part of the coreboot project.
+ *
+ * Copyright (c) 2011 Sven Schnelle 
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License as
+ * published by the Free Software Foundation; version 2 of
+ * the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License
+ * along with this program; if not, write to the Free Software
+ * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
+ * MA 02110-1301 USA
+ */
+
+
+Scope (_SI)
+{
+	Method(_SST, 1, NotSerialized)
+	{
+		If (LEqual (Arg0, 0)) {
+			/* Indicator off */
+
+			/* power LED off */
+			_SB.PCI0.LPC.EC.LED(0x00)
+			/* suspend LED off */
+			_SB.PCI0.LPC.EC.LED(0x07)
+		}
+
+		If (LEqual (Arg0, 1)) {
+			/* working state */
+
+			/* power LED on */
+			_SB.PCI0.LPC.EC.LED(0x80)
+			/* suspend LED off */
+			_SB.PCI0.LPC.EC.LED(0x07)
+		}
+
+		If (LEqual (Arg0, 2)) {
+			/* waking state */
+
+			/* power LED om */
+			_SB.PCI0.LPC.EC.LED(0x80)
+			/* suspend LED blinking */
+			_SB.PCI0.LPC.EC.LED(0xc7)
+		}
+
+		If (LEqual (Arg0, 3)) {
+			/* sleep state */
+
+			/* power LED off */
+			_SB.PCI0.LPC.EC.LED(0x00)
+			/* suspend LED on */
+			_SB.PCI0.LPC.EC.LED(0x87)
+		}
+		
+		
+		
+	}
+}

Modified: trunk/src/mainboard/lenovo/x60/dsdt.asl
==============================================================================
--- trunk/src/mainboard/lenovo/x60/dsdt.asl	Mon Mar 14 10:08:27 2011	(r6443)
+++ trunk/src/mainboard/lenovo/x60/dsdt.asl	Mon Mar 14 14:42:08 2011	(r6444)
@@ -42,7 +42,8 @@

// Thermal Zone
    #include "acpi/thermal.asl"
-
+	// System status indicators
+	#include "acpi/systemstatus.asl
    Scope (_SB) {
    	Device (PCI0)
    	{