New subject: Change in ...coreboot[master]: ec/apple: Add ACPI code for Apple MacBooks

30 May 2019

Evgeny Zinoviev has uploaded this change for review. ( https://review.coreboot.org/c/coreboot/+/33102
Change subject: ec/apple: ACPI code for Apple MacBooks
......................................................................
ec/apple: ACPI code for Apple MacBooks
Move ACPI code for Apple MacBooks to a separate directory to avoid it's
duplication in mainboards.
AC and LID implementation files are named by EC register that's used
in them. Older generations (macbook2,1) use 0x01 while newer
generations like 2011-2012 Airs use 0x60. Battery registers seem to be
the same.
Tested on MacBook Air 5,2.
Change-Id: I3d4585aac8e3ebbfed6ce4d4e39fbc33ac983069
Signed-off-by: Evgeny Zinoviev me@ch1p.io
---
A src/ec/apple/acpi/ac_01.asl
A src/ec/apple/acpi/ac_60.asl
A src/ec/apple/acpi/battery.asl
A src/ec/apple/acpi/ec.asl
A src/ec/apple/acpi/lid_01.asl
A src/ec/apple/acpi/lid_60.asl
6 files changed, 405 insertions(+), 0 deletions(-)
git pull ssh://review.coreboot.org:29418/coreboot refs/changes/02/33102/1

diff --git a/src/ec/apple/acpi/ac_01.asl b/src/ec/apple/acpi/ac_01.asl
new file mode 100644
index 0000000..86966ae8
--- /dev/null
+++ b/src/ec/apple/acpi/ac_01.asl
@@ -0,0 +1,42 @@
+
+ * This file is part of the coreboot project.
+ *
+ * Copyright (c) 2019 Evgeny Zinoviev me@ch1p.io
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License as
+ * published by the Free Software Foundation; version 2 of
+ * the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ */
+
+Scope(_SB.PCI0.LPCB.EC)
+{
+    Field(ERAM, ByteAcc, NoLock, Preserve)
+    {
+        Offset(0x01),
+                  1,
+            HPAC, 1,  /* AC status */
+    }
+
+    Device(AC)
+    {
+        Name(_HID, "ACPI0003")
+        Name(_UID, 0x00)
+        Name(_PCL, Package() { _SB } )
+
+        Method(_PSR, 0, NotSerialized)
+        {
+            return(HPAC)
+        }
+
+        Method(_STA, 0, NotSerialized)
+        {
+            Return(0x0f)
+        }
+    }
+}
diff --git a/src/ec/apple/acpi/ac_60.asl b/src/ec/apple/acpi/ac_60.asl
new file mode 100644
index 0000000..76adea1
--- /dev/null
+++ b/src/ec/apple/acpi/ac_60.asl
@@ -0,0 +1,42 @@
+/*
+ * This file is part of the coreboot project.
+ *
+ * Copyright (c) 2019 Evgeny Zinoviev me@ch1p.io
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License as
+ * published by the Free Software Foundation; version 2 of
+ * the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ */
+
+Scope(_SB.PCI0.LPCB.EC)
+{
+    Field(ERAM, ByteAcc, NoLock, Preserve)
+    {
+        Offset(0x60),
+                , 1,
+            HPAC, 1,  /* AC status */
+    }
+
+    Device(AC)
+    {
+        Name(_HID, "ACPI0003")
+        Name(_UID, 0x00)
+        Name(_PCL, Package() { _SB } )
+
+        Method(_PSR, 0, NotSerialized)
+        {
+            return(HPAC)
+        }
+
+        Method(_STA, 0, NotSerialized)
+        {
+            Return(0x0f)
+        }
+    }
+}
diff --git a/src/ec/apple/acpi/battery.asl b/src/ec/apple/acpi/battery.asl
new file mode 100644
index 0000000..f1706be
--- /dev/null
+++ b/src/ec/apple/acpi/battery.asl
@@ -0,0 +1,163 @@
+/*
+ * This file is part of the coreboot project.
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; version 2 of the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ */
+
+Field(ERAM, ByteAcc, NoLock, Preserve)
+{
+	Offset(0x20),
+		SPTR,   8,
+		SSTS,   8,
+		SADR,   8,
+		SCMD,   8,
+		SBFR,   256,
+}
+
+Field(ERAM, ByteAcc, Lock, Preserve)
+{
+	Offset(0x24),
+		SBDW,   16,
+}
+
+Method(SBPC, 0, NotSerialized)
+{
+	Store(1000, Local0)
+	While(Local0)
+	{
+		If(LEqual(SPTR, 0x00))
+		{
+			Return()
+		}
+
+		Sleep(1)
+		Decrement(Local0)
+	}
+}
+
+Method(SBRW, 2, NotSerialized)
+{
+	Acquire(ECLK, 0xFFFF)
+	Store(ShiftLeft(Arg0, 0x01), SADR)
+	Store(Arg1, SCMD)
+	Store(0x09, SPTR)
+	SBPC()
+	Store(SBDW, Local0)
+	Release(ECLK)
+	Return(Local0)
+}
+
+Method(SBRB, 2, NotSerialized)
+{
+	Acquire(ECLK, 0xFFFF)
+	Store(ShiftLeft(Arg0, 0x01), SADR)
+	Store(Arg1, SCMD)
+	Store(0x0B, SPTR)
+	SBPC()
+	Store(SBFR, Local0)
+	Release(ECLK)
+	Return(Local0)
+}
+
+Device(BAT0)
+{
+	Name(_HID, EisaId("PNP0C0A"))
+	Name(_UID, 0x00)
+	Name(_PCL, Package() { _SB })
+
+	Name(BATS, Package()
+	{
+		0x00,			// 0: PowerUnit: Report in mWh
+		0xFFFFFFFF,		// 1: Design cap
+		0xFFFFFFFF,		// 2: Last full charge cap
+		0x01,			// 3: Battery Technology
+		10800,			// 4: Design Voltage(mV)
+		0x00,			// 5: Warning design capacity
+		200,			// 6: Low design capacity
+		10,			// 7: granularity1
+		10,			// 8: granularity2
+		"",			// 9: Model number
+		"",			// A: Serial number
+		"",			// B: Battery Type
+		""			// C: OEM information
+	})
+
+	Name(BATI, Package()
+	{
+		0,			// Battery State
+					// Bit 0 - discharge
+					// Bit 1 - charge
+					// Bit 2 - critical state
+		0,			// Battery present Rate
+		0,			// Battery remaining capacity
+		0			// Battery present voltage
+	})
+
+	Method(_BIF, 0, NotSerialized)
+	{
+		Multiply(^^SBRW(0x0B, 0x18), 10, Index(BATS, 0x01))
+		Multiply(^^SBRW(0x0B, 0x10), 10, Index(BATS, 0x02))
+		Store(^^SBRW(0x0B, 0x19), Index(BATS, 0x04))
+		Store(^^SBRB(0x0B, 0x21), Index(BATS, 0x09))
+		Store(^^SBRB(0x0B, 0x22), Index(BATS, 0x0B))
+		Store(^^SBRB(0x0B, 0x20), Index(BATS, 0x0C))
+
+		Return(BATS)
+	}
+
+	Method(_STA, 0, NotSerialized)
+	{
+		If(And(^^SBRW(0x0A, 0x01), 0x01)) {
+			Return(0x1f)
+		} else {
+			Return(0x0f)
+		}
+	}
+
+	Method(_BST, 0, NotSerialized)
+	{
+		/* Check for battery presence.  */
+		If(LNot(And(^^SBRW(0x0A, 0x01), 0x01))) {
+			Return(Package(4) {
+			       0,
+			       0xFFFFFFFF,
+			       0xFFFFFFFF,
+			       0xFFFFFFFF
+			})
+		}
+		Store(^^SBRW(0x0B, 0x09), Local1)
+		Store(Local1, Index(BATI, 0x03))
+		Store(^^SBRW(0x0B, 0x0A), Local0)
+		/* Sign-extend Local0.  */
+		If(And(Local0, 0x8000))
+		{
+			Not(Local0, Local0)
+			And(Increment(Local0), 0xFFFF, Local0)
+		}
+
+		Multiply(Local0, Local1, Local0)
+		Divide(Local0, 1000, , Index(BATI, 1))
+		Multiply(^^SBRW(0x0B, 0x0F), 10, Index(BATI, 2))
+		If(HPAC)
+		{
+			If(LNot(And(^^SBRW(0x0B, 0x16), 0x40))) {
+				Store(2, Index(BATI, 0))
+			} Else {
+				Store(0, Index(BATI, 0))
+			}
+		}
+		Else
+		{
+			Store(0x01, Index(BATI, 0))
+		}
+
+		Return(BATI)
+	}
+}
diff --git a/src/ec/apple/acpi/ec.asl b/src/ec/apple/acpi/ec.asl
new file mode 100644
index 0000000..982011c
--- /dev/null
+++ b/src/ec/apple/acpi/ec.asl
@@ -0,0 +1,56 @@
+/*
+ * This file is part of the coreboot project.
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; version 2 of the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ */
+
+Device(EC)
+{
+	Name(_HID, EISAID("PNP0C09"))
+	Name(_UID, 0)
+
+	Name(_GPE, 0x17)
+	Mutex(ECLK, 0)
+
+	OperationRegion(ERAM, EmbeddedControl, 0x00, 0x100)
+
+	/* LID status change. */
+	Method(_Q20, 0, NotSerialized)
+	{
+		Notify(LID, 0x80)
+	}
+
+	/* AC status change. */
+	Method(_Q21, 0, NotSerialized)
+	{
+		Notify(AC, 0x80)
+	}
+
+	Method(_CRS, 0)
+	{
+		Name(ECMD, ResourceTemplate()
+		{
+			IO(Decode16, 0x62, 0x62, 1, 1)
+			IO(Decode16, 0x66, 0x66, 1, 1)
+		})
+		Return(ECMD)
+	}
+
+	Method(_PRW, 0, NotSerialized)
+	{
+		return (Package () { 0x23, 0x04 })
+	}
+
+	Method(_INI, 0, NotSerialized)
+	{
+	}
+
+#include "battery.asl"
+}
diff --git a/src/ec/apple/acpi/lid_01.asl b/src/ec/apple/acpi/lid_01.asl
new file mode 100644
index 0000000..88ad045
--- /dev/null
+++ b/src/ec/apple/acpi/lid_01.asl
@@ -0,0 +1,51 @@
+/*
+ * This file is part of the coreboot project.
+ *
+ * Copyright (c) 2019 Evgeny Zinoviev me@ch1p.io
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License as
+ * published by the Free Software Foundation; version 2 of
+ * the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ */
+
+Scope(_SB.PCI0.LPCB.EC)
+{
+    Field(ERAM, ByteAcc, NoLock, Preserve)
+    {
+        Offset(0x01),
+            LIDS, 1,   /* Lid status */
+
+        Offset(0x02),
+            WKLD, 1,   /* Lid wake */
+    }
+
+    Device(LID)
+    {
+        Name(_HID, "PNP0C0D")
+
+        Method(_LID, 0, NotSerialized)
+        {
+            return(LIDS)
+        }
+
+        Method(_PRW, 0, NotSerialized)
+        {
+            Return (Package() { 0x1d, 0x03 })
+        }
+
+        Method(_PSW, 1, NotSerialized)
+        {
+            if (Arg0) {
+                Store(1, WKLD)
+            } else {
+                Store(0, WKLD)
+            }
+        }
+    }
+}
diff --git a/src/ec/apple/acpi/lid_60.asl b/src/ec/apple/acpi/lid_60.asl
new file mode 100644
index 0000000..e0836b6
--- /dev/null
+++ b/src/ec/apple/acpi/lid_60.asl
@@ -0,0 +1,51 @@
+/*
+ * This file is part of the coreboot project.
+ *
+ * Copyright (c) 2019 Evgeny Zinoviev me@ch1p.io
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License as
+ * published by the Free Software Foundation; version 2 of
+ * the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ */
+
+Scope(_SB.PCI0.LPCB.EC)
+{
+    Field(ERAM, ByteAcc, NoLock, Preserve)
+    {
+        Offset(0x60),
+            LIDS, 1,  /* Lid status */
+
+        Offset(0x68),
+            WKLD, 1,  /* Lid wake */
+    }
+
+    Device(LID)
+    {
+        Name(_HID, "PNP0C0D")
+
+        Method(_LID, 0, NotSerialized)
+        {
+            return(LIDS)
+        }
+
+        Method(_PRW, 0, NotSerialized)
+        {
+            Return (Package() { 0x23, 0x04 })
+        }
+
+        Method(_PSW, 1, NotSerialized)
+        {
+            if (Arg0) {
+                Store(1, WKLD)
+            } else {
+                Store(0, WKLD)
+            }
+        }
+    }
+}
-- 
To view, visit https://review.coreboot.org/c/coreboot/+/33102
To unsubscribe, or for help writing mail filters, visit https://review.coreboot.org/settings

Gerrit-Project: coreboot
Gerrit-Branch: master
Gerrit-Change-Id: I3d4585aac8e3ebbfed6ce4d4e39fbc33ac983069
Gerrit-Change-Number: 33102
Gerrit-PatchSet: 1
Gerrit-Owner: Evgeny Zinoviev me@ch1p.com
Gerrit-MessageType: newchange



    

Change in ...coreboot[master]: ec/apple: ACPI code for Apple MacBooks