openfirmware

openfirmware@openfirmware.info

3007 discussions

[commit] r2172 - cpu/arm/olpc/1.75
by repository service 07 Feb '11

07 Feb '11

Author: wmb Date: Mon Feb 7 06:15:08 2011 New Revision: 2172 URL: http://tracker.coreboot.org/trac/openfirmware/changeset/2172 Log: XO-1.75 - Checked in viaedi.fth - reflashes XO-1.75 A2 EC firmware using a cable from an XO-1.5 Added: cpu/arm/olpc/1.75/viaedi.fth Added: cpu/arm/olpc/1.75/viaedi.fth ============================================================================== --- /dev/null 00:00:00 1970 (empty, because file is newly added) +++ cpu/arm/olpc/1.75/viaedi.fth Mon Feb 7 06:15:08 2011 (r2172) @@ -0,0 +1,338 @@ +purpose: Recover EC FLASH on XO-1.75 A2 using cable from XO-1.5 + +\ HOWTO USE THIS +\ Put this file and ecimage.bin (32768 bytes) on a USB stick, insert into XO-1.5 +\ Connect 6-pin programming cable from XO-1.5 recovery driver port (J3) to +\ XO-1.75 A2 EDI "REFLASH EC HEADER" (J3) +\ Power on XO-1.5 +\ Power on XO-1.75 +\ ok fload u:\viaedi.fth +\ ok select /spi +\ ok recover-ec + +dev /spi + +: pio16mhz ( -- ) + h# 01 h# 6c spi-b! \ 33/(2*1) MHz + h# 00 h# 6e spi-b! \ No special clocking + h# 08 h# 6d spi-b! \ Dynamic clock, PIO mode, command posted write off +; +: pio1.5mhz ( -- ) + d# 11 h# 6c spi-b! \ 33/(2*11) = 1.5 MHz + h# 00 h# 6e spi-b! \ No special clocking + h# 08 h# 6d spi-b! \ Dynamic clock, PIO mode, command posted write off +; + +: edi-go ( -- ) + h# 802 spi-cmd! ( ) \ Set go bit + wait-done ( ) \ Wait for done bit + 0 spi-cmd! ( ) \ Clear go bit + \ The go bit must be cleared before clear-done, otherwise clear-done will not work + clear-done ( ) \ Clear done bit +; + +variable access-count 0 access-count ! +variable out-ptr +variable #in-bytes +: spi-cs-on ( -- ) +\ access-count @ 1 = if pio8mhz 2 access-count ! then +\ access-count @ 0= if pio1.5mhz 1 access-count ! then + 8 out-ptr ! 0 #in-bytes ! +; +: spi-out ( b -- ) out-ptr @ spi-b! 1 out-ptr +! ; +: spi-cs-off ( -- ) + out-ptr @ 8 - ( #out-bytes ) + dup 0= if drop exit then ( #out-bytes ) + #in-bytes @ + 8 lshift 2 or spi-cmd! + wait-done + 0 spi-cmd! + clear-done +; +: spi-in ( -- b ) + 1 #in-bytes ! + spi-cs-off + out-ptr @ spi-b@ + 8 out-ptr ! +; + +: edi-wait-b ( -- b ) + 4 #in-bytes ! + spi-cs-off + out-ptr @ #in-bytes @ bounds ?do + i spi-b@ h# 50 = if + i 1+ spi-b@ unloop exit + then + loop + true abort" Did not receive EDI data ready byte" +; + +\ This cheats by assuming how long it takes for the data to return +\ It's interesting as an example of how fast the hardware can go. +: edi-really-fast-next-b@ ( -- b ) + h# 33 8 spi-b! + h# 402 spi-cmd! wait-done + 0 spi-cmd! + clear-done + b spi-b@ +; + + +\ *** Start of verbatim inclusion of edi.fth + +\ The following code depends on externally-privided low-level SPI bus +\ access primitives that are defined in "bbedi.fth" for the "native" +\ case (EC and CPU on the same machine). They can also be implemented +\ for tethered programming from a different machine like an XO-1.5. +\ +\ Low-level primitives: +\ spi-start ( -- ) - Init SPI bus +\ spi-cs-on ( -- ) - Assert SPI-bus CS# +\ spi-cs-off ( -- ) - Deassert SPI-bus CS# +\ spi-out ( byte -- ) - Send byte +\ spi-in ( -- byte ) - Receive byte + +d# 128 constant /flash-page + +: edi-cmd,adr ( offset cmd -- ) \ Send command plus 3 address bytes + spi-cs-on ( offset cmd ) + spi-out ( offset ) + lbsplit drop spi-out spi-out spi-out ( ) +; +: edi-b! ( byte offset -- ) \ Write byte to address inside EC chip + h# 40 edi-cmd,adr spi-out spi-cs-off +; +[ifndef] edi-wait-b +: edi-wait-b ( -- b ) \ Wait for and receive EC response byte + d# 10 0 do + spi-in h# 50 = if + spi-in ( b ) + spi-cs-off ( b ) + unloop exit + then + loop + spi-cs-off + true abort" EDI byte in timeout" +; +[then] +: edi-b@ ( offset -- b ) \ Read byte from address inside EC chip + h# 30 edi-cmd,adr edi-wait-b +; +: edi-next-b@ ( -- b ) \ Read the next EC byte - auto-increment address + spi-cs-on h# 33 spi-out edi-wait-b +; +: edi-disable ( -- ) \ Turn off the EC EDI interface + spi-cs-on + h# f3 spi-out + spi-in ( b ) + spi-cs-off + h# 8c <> if + ." Unexpected response from edi-disable" cr + then +; + +0 [if] +: edi-w@ ( offset -- w ) \ Read 16-bit word from address inside EC chip + dup 1+ edi-b@ ( offset b.low ) + swap edi-b@ ( b.low b.high ) + bwjoin +; +[else] +: edi-w@ ( offset -- w ) \ Read 16-bit word from address inside EC chip + edi-b@ edi-next-b@ swap bwjoin +; +[then] +: reset-8051 ( -- ) \ Reset 8-5 + h# f010 edi-b@ 1 or h# f010 edi-b! +; +: unreset-8051 ( -- ) \ Reset 8-5 + h# f010 edi-b@ 1 invert and h# f010 edi-b! +; + +\ 0 in bit 0 selects masked ROM as code source for 8051, 1 selects FLASH +\ The 8051 should be in reset mode when changing that bit. +: select-flash ( -- ) \ Setup for access to FLASH inside the EC + h# f011 edi-b@ 1 or h# f011 edi-b! +; + +: probe-rdid ( -- found? ) \ Verify that the EC is the one we think it is + select-flash + h# f01c ['] edi-w@ catch if ( x ) + drop false exit ( -- false ) + then ( id ) + + 1 invert and h# 3730 = +; + +: wait-flash-busy ( -- ) \ Wait for an erase/programming operation to complete + get-msecs h# 1000 + ( limit ) + begin ( limit ) + h# fea0 edi-b@ ( limit b ) + h# 80 and if ( limit ) + drop exit + then ( limit ) + dup get-msecs - 0<= ( limit timeout? ) + until ( limit ) + drop + true abort" EDI FLASH busy timeout" +; + +: flash-cmd ( b -- ) h# fea7 edi-b! ; + +: set-offset ( offset -- ) + wbsplit ( offset-low offset-hi ) + h# fea9 edi-b! h# fea8 edi-b! ( ) +; + +: erase-page ( offset -- ) + wait-flash-busy ( offset ) + set-offset ( ) + h# 20 flash-cmd ( ) +; + +: erase-chip ( -- ) wait-flash-busy h# 60 flash-cmd wait-flash-busy ; + +: send-byte ( b offset -- ) set-offset h# feaa edi-b! 2 flash-cmd ; + +: edi-program-page ( adr offset -- ) + \ Clear HVPL + wait-flash-busy h# 80 flash-cmd ( adr offset ) + + \ Fill the page buffer + swap /flash-page bounds do ( offset ) + i c@ over send-byte ( offset ) + 1+ ( offset' ) + loop ( offset ) + drop ( ) + + \ Commit the buffer to the FLASH memory + wait-flash-busy ( ) \ Redundant wait? + h# 70 flash-cmd ( ) + wait-flash-busy ( ) +; +: edi-program-flash ( adr len offset -- ) + swap 0 ?do + over i + over i + edi-program-page ( adr offset ) + /flash-page +loop ( adr offset ) + 2drop +; +: edi-read-flash ( adr len offset -- ) + over 0= if 3drop exit then ( adr len offset ) + edi-b@ ( adr len byte ) + third c! ( adr len ) + 1 /string bounds ?do ( ) + edi-next-b@ i c! ( ) + loop ( ) +; +: trim@ ( offset -- b ) + set-offset + h# 90 flash-cmd + wait-flash-busy + h# feab edi-b@ +; +: trim-tune ( -- ) +\ firmware-id 0= if + \ Read trim data and write to register (for ENE macros) + h# 100 trim@ h# 5a = if + \ Low Voltage Detect TRIM register + h# f035 edi-b@ ( val ) + h# 1f invert and ( val' ) + h# 101 trim@ h# 1f and or ( val' ) + h# f035 edi-b! ( ) + + \ Int Oscillator Control register - HKCOMOS32K + h# f02b edi-b@ ( val ) + h# 0f invert and ( val' ) + h# 102 trim@ h# 0f and or ( val' ) + h# f02b edi-b! ( ) + then + + \ Read trim data and write to register (for HHNEC macros) + h# 1ff trim@ 0<> if + \ XBIMISC register - S[4:0] + h# fea6 edi-b@ ( val ) + h# 1f invert and ( val' ) + h# 1f0 trim@ h# 1f and or ( val' ) + h# fea6 edi-b! ( ) + + \ XBI Pump IP register - Pdac[3:0] | Ndac[3:0] + h# 1f1 trim@ 4 lshift ( val ) + h# 1f2 trim@ h# 0f and or ( val' ) + h# fea3 edi-b! ( ) + + \ XBI Flash IP register - Bdac[3:0] + h# fea4 edi-b@ ( val ) + h# 0f invert and ( val' ) + h# 1f4 trim@ h# 0f and or ( val' ) + h# fea4 edi-b! ( ) + + \ XB VR IP register - Tctrim[3:0] | Abstrim[3:0] (Vref temp coef and absolute value) + h# 1f5 trim@ 4 lshift ( val ) + h# 1f6 trim@ h# 0f and or ( val' ) + h# fea5 edi-b! ( ) + + \ XBI Flash IP register - Itim[3:0] - Must be last + h# fea4 edi-b@ ( val ) + h# f0 invert and ( val' ) + h# 1f4 trim@ 4 lshift or ( val' ) + h# fea4 edi-b! ( ) + + 3 us \ Required after Itim[3:0] update + + \ XBI Embedded Flash Configuration register + h# 10 h# fea0 edi-b! \ Set FLASH clock + + h# fea0 edi-b@ h# d0 = if + ." Warning - XBIECFG is 0xd0" cr + then + then +\ then +; +: edi-open ( -- ) + \ slow-edi-clock \ Target speed between 1 and 2 MHz + spi-start + \ The first operation often fails so retry it + ['] select-flash catch if select-flash then + reset-8051 + trim-tune + \ fast-edi-clock \ Target speed up to 16 MHz + \ reset +; +\ *** End of verbatim inclusion of edi.fth + +: recover-ec ( -- ) + pio1.5mhz + edi-open + " u:\ecimage.bin" $read-file abort" Read error" ( adr len ) + erase-chip ( adr len ) + 2dup 0 edi-program-flash ( adr len ) + load-base 8000 0 edi-read-flash ( adr len ) + 2dup load-base swap comp if ." Different" then ( adr len ) + free-mem ( ) +; + +dend + + +\ LICENSE_BEGIN +\ Copyright (c) 2009 FirmWorks +\ +\ Permission is hereby granted, free of charge, to any person obtaining +\ a copy of this software and associated documentation files (the +\ "Software"), to deal in the Software without restriction, including +\ without limitation the rights to use, copy, modify, merge, publish, +\ distribute, sublicense, and/or sell copies of the Software, and to +\ permit persons to whom the Software is furnished to do so, subject to +\ the following conditions: +\ +\ The above copyright notice and this permission notice shall be +\ included in all copies or substantial portions of the Software. +\ +\ THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, +\ EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF +\ MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND +\ NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE +\ LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION +\ OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION +\ WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE. +\ +\ LICENSE_END

1 0

[commit] r2171 - dev/usb2/device/keyboard
by repository service 04 Feb '11

04 Feb '11

Author: wmb Date: Fri Feb 4 22:10:33 2011 New Revision: 2171 URL: http://tracker.coreboot.org/trac/openfirmware/changeset/2171 Log: USB keyboard driver - fixed typos in commentary caused by a search and replace error. Modified: dev/usb2/device/keyboard/keycode.fth Modified: dev/usb2/device/keyboard/keycode.fth ============================================================================== --- dev/usb2/device/keyboard/keycode.fth Fri Feb 4 02:42:59 2011 (r2170) +++ dev/usb2/device/keyboard/keycode.fth Fri Feb 4 22:10:33 2011 (r2171) @@ -102,7 +102,7 @@ then ; -\ Searascii for a matascii for "byte" in the "key" position of the table at +\ Search for a match for "byte" in the "key" position of the table at \ "table-adr". If a match is found, return the corresponding "value" byte \ and true. Otherwise return the argument byte and false. The table \ consists of pairs of bytes - the first byte of the pair is "key" and

1 0

[commit] r2170 - cpu/arm/olpc/1.75
by repository service 04 Feb '11

04 Feb '11

Author: wmb Date: Fri Feb 4 02:42:59 2011 New Revision: 2170 URL: http://tracker.coreboot.org/trac/openfirmware/changeset/2170 Log: XO-1.75 touchscreen selftest - dim old tracks instead of erasing them. Modified: cpu/arm/olpc/1.75/exc7200-touchscreen.fth Modified: cpu/arm/olpc/1.75/exc7200-touchscreen.fth ============================================================================== --- cpu/arm/olpc/1.75/exc7200-touchscreen.fth Fri Feb 4 02:42:30 2011 (r2169) +++ cpu/arm/olpc/1.75/exc7200-touchscreen.fth Fri Feb 4 02:42:59 2011 (r2170) @@ -166,10 +166,15 @@ ; 0 value pressure +: *3/5 ( n -- n' ) 3 5 */ ; +: dimmer ( color -- color' ) + 565>rgb rot *3/5 rot *3/5 rot *3/5 rgb>565 +; + : track ( x y z down? contact# -- ) setcolor ( x y z down? ) 0= if - pixcolor @ black " replace-color" $call-screen + pixcolor @ dup dimmer " replace-color" $call-screen 3drop exit then ( x y z ) to pressure ( x y )

1 0

[commit] r2169 - cpu/arm/olpc/1.75
by repository service 04 Feb '11

04 Feb '11

Author: wmb Date: Fri Feb 4 02:42:30 2011 New Revision: 2169 URL: http://tracker.coreboot.org/trac/openfirmware/changeset/2169 Log: XO-1.75 touchscreen demo - zooms and pans the screen image with gestures. Added: cpu/arm/olpc/1.75/pinch.fth Modified: cpu/arm/olpc/1.75/fw.bth Modified: cpu/arm/olpc/1.75/fw.bth ============================================================================== --- cpu/arm/olpc/1.75/fw.bth Thu Feb 3 21:05:52 2011 (r2168) +++ cpu/arm/olpc/1.75/fw.bth Fri Feb 4 02:42:30 2011 (r2169) @@ -164,6 +164,9 @@ fload ${BP}/cpu/x86/pc/olpc/via/copynand.fth fload ${BP}/cpu/arm/olpc/1.75/exc7200-touchscreen.fth \ Touchscreen driver and diagnostic +fload ${BP}/cpu/arm/olpc/1.75/pinch.fth \ Touchscreen gestures +: pinch " pinch" screen-ih $call-method ; + fload ${BP}/cpu/arm/mmp2/keypad.fth [ifndef] cl2-a1 stand-init: keypad Added: cpu/arm/olpc/1.75/pinch.fth ============================================================================== --- /dev/null 00:00:00 1970 (empty, because file is newly added) +++ cpu/arm/olpc/1.75/pinch.fth Fri Feb 4 02:42:30 2011 (r2169) @@ -0,0 +1,188 @@ +\ See license at end of file +purpose: Zoom and pan the text scroller with touchscreen gestures + +dev screen +: dst-size@ ( -- w h ) h# 108 lcd@ lwsplit ; +: dst-size! ( w h -- ) wljoin h# 108 lcd! ; +: dst-offset@ ( -- x y ) h# 100 lcd@ lwsplit ; +: dst-offset! ( x y -- ) wljoin h# 100 lcd! ; +: scr-size@ ( -- w h ) h# 104 lcd@ lwsplit ; +: half-size ( -- w h ) dst-size@ swap 2/ swap 2/ ; +: image-center-xy ( -- x y ) half-size dst-offset@ xy+ ; + +: xy-max ( x1 y1 x2 y2 -- xmax ymax ) rot max >r max r> ; +: xy-min ( x1 y1 x2 y2 -- xmin ymin ) rot min >r min r> ; +d# 60 d# 80 2constant min-wh +: set-dst-size ( w h -- ) + scr-size@ xy-min min-wh xy-max dst-size! +; +\ This is an attempt to delay the operation until "retrace", but +\ it doesn't work very well; it's currently worse than nothing. +: wait-frame ( -- ) + 0 h# 1c4 lcd! begin h# 1c4 lcd@ until +; +: set-dst-offset ( x y -- ) + \ Keep the full image on-screen + 0 0 xy-max ( x' y' ) + + 2dup dst-size@ xy+ ( x y extent-x extent-y ) + scr-size@ 2swap xy- ( x y margin-x margin-y ) + \ A negative margin means part of the image is off the screen + \ Positive margin is okay; we only adjust if margin is negative. + 0 0 xy-min ( x y adjust-x adjust-y ) + xy+ ( x' y' ) + + dst-offset! ( ) +; +: resize-image ( xnum ynum xdenom ydenom old-w old-h -- ) + 2>r ( xnum xdenom ynum ydenom r: w h ) + rot swap ( xnum xdenom ynum ydenom r: w h ) + 2r> ( xnum xdenom ynum ydenom w h ) + swap >r ( xnum xdenom ynum ydenom h r: w ) + -rot */ ( xnum xdenom h' r: w ) + r> swap >r ( xnum xdenom w r: h' ) + -rot */ ( w' r: h' ) + r> ( w' h' ) + set-dst-size ( ) +; +: rx ( 6*n -- 6*n ) 0 5 do i pick .d -1 +loop cr resize-image ; +: arx ." A " rx resize-image ; +: brx ." B " rx resize-image ; + +0 0 2value p0 +0 0 2value p1 +0 0 2value base-distance +0 0 2value base-wh +0 0 2value base-touch-xy +0 0 2value base-center-xy + +\ Try to keep the center of the image in the same place after resizing +: recenter-image ( -- ) + base-center-xy half-size xy- + set-dst-offset +; + +0 value down0? +0 value down1? + +: distance ( -- x y ) p1 p0 xy- ; + +: xy-abs ( x y -- abs-x abs-y ) swap abs swap abs ; + +0 value touch-ih +: open-touch ( -- ) + touch-ih 0= if + " /touchscreen" open-dev to touch-ih + then + touch-ih 0= abort" Can't open touchscreen" +; +: close-touch ( -- ) touch-ih ?dup if close-dev 0 to touch-ih then ; + +: mark-touch ( -- ) + p0 to base-touch-xy + image-center-xy to base-center-xy +; +: mark-size ( -- ) + dst-size@ to base-wh + distance xy-abs to base-distance +; +: move-image ( newx,y -- ) +\ wait-frame + base-touch-xy xy- base-center-xy half-size xy- xy+ set-dst-offset +; +: resize&recenter ( -- ) +\ wait-frame + distance xy-abs base-distance base-wh resize-image \ brx + recenter-image +; +: do-touch0 ( x y down? -- ) + -rot to p0 if ( ) \ Down + down1? if \ Double-touch - resize + down0? if \ Not the initial touch pair - resize the screen image + resize&recenter + else \ Initial touch pair - establish the baseline size + mark-size + then + else \ The second finger is up, so this is a move + down0? if \ Not the initial touch - move the image + p0 move-image + else \ Initial touch - establish the base position + mark-touch + then + then + + true to down0? + else \ Up + false to down0? + then +; +: do-touch1 ( x y down? -- ) + -rot to p1 if ( ) \ Down + down0? if \ Double-touch - resize + down1? if \ Not the initial touch pair - resize the window + resize&recenter + else \ Initial touch pair - establish the baseline size + mark-size + + \ Initial touch of second finger - reestablish the base position + \ in case the image was moved after the first finger when down + mark-touch + then + else \ The first finger is now up - do nothing in this case + then + + true to down1? + else \ Up + \ When the second finger goes up, we again must reestablish the base position + \ so subsequent movement of the first finger will cause stable image movement + mark-touch + false to down1? + then +; +: touch>screen ( x y -- x' y' ) + scr-size@ 1 1 xy- xy* + swap d# 15 rshift swap d# 15 rshift +; +: do-gesture ( -- ) + " get-touch?" touch-ih $call-method 0= if exit then ( x y z down? touch# ) + 2>r ( x y z r: down? touch# ) + drop ( x y r: down? touch# ) + \ Convert from touchscreen to pixel coordinates + touch>screen ( x y r: down? touch# ) + 2r> ( x y down? touch# ) + case + 0 of do-touch0 endof + 1 of do-touch1 endof + ( default ) >r 3drop r> + endcase +; +: pinch + open-touch + begin do-gesture key? until + close-touch +; +dend + +\ LICENSE_BEGIN +\ Copyright (c) 2011 FirmWorks +\ +\ Permission is hereby granted, free of charge, to any person obtaining +\ a copy of this software and associated documentation files (the +\ "Software"), to deal in the Software without restriction, including +\ without limitation the rights to use, copy, modify, merge, publish, +\ distribute, sublicense, and/or sell copies of the Software, and to +\ permit persons to whom the Software is furnished to do so, subject to +\ the following conditions: +\ +\ The above copyright notice and this permission notice shall be +\ included in all copies or substantial portions of the Software. +\ +\ THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, +\ EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF +\ MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND +\ NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE +\ LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION +\ OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION +\ WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE. +\ +\ LICENSE_END

1 0

[commit] r2168 - cpu/x86/pc/olpc
by repository service 03 Feb '11

03 Feb '11

Author: wmb Date: Thu Feb 3 21:05:52 2011 New Revision: 2168 URL: http://tracker.coreboot.org/trac/openfirmware/changeset/2168 Log: OLPC XO-1 - restart after botched resume, instead of interacting. The problem happens extremely infrequently, so there is no longer any interest in debugging it (it's probably an obscure race condition between OS shutdown and power-button-to-suspend handling). Modified: cpu/x86/pc/olpc/fw.bth Modified: cpu/x86/pc/olpc/fw.bth ============================================================================== --- cpu/x86/pc/olpc/fw.bth Thu Feb 3 08:00:20 2011 (r2167) +++ cpu/x86/pc/olpc/fw.bth Thu Feb 3 21:05:52 2011 (r2168) @@ -603,9 +603,9 @@ : ?resume-botch h# 1454 pl@ 2 and if red-letters - ." Interacting due to botched resume" cr + ." Restarting due to botched resume" cr black-letters - hex interact + bye then ;

1 0

[commit] r2167 - cpu/arm/olpc/1.75
by repository service 03 Feb '11

03 Feb '11

Author: wmb Date: Thu Feb 3 08:00:20 2011 New Revision: 2167 URL: http://tracker.coreboot.org/trac/openfirmware/changeset/2167 Log: XO-1.75 RTC driver - call set-address in bcd-time&date so other TWSI users don't interfere with it. Modified: cpu/arm/olpc/1.75/rtc.fth Modified: cpu/arm/olpc/1.75/rtc.fth ============================================================================== --- cpu/arm/olpc/1.75/rtc.fth Thu Feb 3 07:59:14 2011 (r2166) +++ cpu/arm/olpc/1.75/rtc.fth Thu Feb 3 08:00:20 2011 (r2167) @@ -31,6 +31,7 @@ : >bcd ( binary -- bcd ) d# 10 /mod 4 << + ; : bcd-time&date ( -- s m h d m y century ) + set-address [ifdef] cl2-a1 7 0 smb-read-n ( s m h dow d m y ) [else]

1 0

[commit] r2166 - cpu/arm/olpc/1.75 ofw/gui
by repository service 03 Feb '11

03 Feb '11

Author: wmb Date: Thu Feb 3 07:59:14 2011 New Revision: 2166 URL: http://tracker.coreboot.org/trac/openfirmware/changeset/2166 Log: Pong - added touchscreen support to pong game. Modified: cpu/arm/olpc/1.75/exc7200-touchscreen.fth cpu/arm/olpc/1.75/fw.bth ofw/gui/ofpong.fth Modified: cpu/arm/olpc/1.75/exc7200-touchscreen.fth ============================================================================== --- cpu/arm/olpc/1.75/exc7200-touchscreen.fth Thu Feb 3 07:58:08 2011 (r2165) +++ cpu/arm/olpc/1.75/exc7200-touchscreen.fth Thu Feb 3 07:59:14 2011 (r2166) @@ -6,6 +6,8 @@ " touchscreen" name : open ( -- okay? ) my-unit " set-address" $call-parent true + \ Read once to prime the interrupt + d# 10 " get" $call-parent 4drop 4drop 2drop ; : close ( -- ) ; : get-touch? ( -- false | x y z down? contact# true ) Modified: cpu/arm/olpc/1.75/fw.bth ============================================================================== --- cpu/arm/olpc/1.75/fw.bth Thu Feb 3 07:58:08 2011 (r2165) +++ cpu/arm/olpc/1.75/fw.bth Thu Feb 3 07:59:14 2011 (r2166) @@ -252,6 +252,7 @@ fload ${BP}/cpu/x86/pc/olpc/via/fsverify.fth devalias fsdisk int:0 +create pong-use-touchscreen fload ${BP}/ofw/gui/ofpong.fth [ifdef] notyet fload ${BP}/cpu/x86/pc/olpc/life.fth Modified: ofw/gui/ofpong.fth ============================================================================== --- ofw/gui/ofpong.fth Thu Feb 3 07:58:08 2011 (r2165) +++ ofw/gui/ofpong.fth Thu Feb 3 07:59:14 2011 (r2166) @@ -7,10 +7,6 @@ 0 value erasecol -1 value drawcol -0 value key_left_up -0 value key_left_down -0 value key_right_up -0 value key_right_down 0 value key_esc 0 value key_off @@ -42,36 +38,39 @@ ballsize 5 * value batsize 1000 value pscale +: scale ( coord -- scaled-coord ) pscale * ; + 0 value ball_limit_x -ballsize pscale * value ball_limit_lo_y +ballsize scale value ball_limit_lo_y 0 value ball_limit_hi_y -ballsize pscale * value bat_limit_lo_y +ballsize scale value bat_limit_lo_y 0 value bat_limit_hi_y 0 value hit_limit_left_lo_x -ballsize 2 * pscale * value hit_limit_left_hi_x +ballsize 2 * scale value hit_limit_left_hi_x 0 value hit_limit_right_lo_x 0 value hit_limit_right_hi_x -ballsize pscale * value reflect_left_x +ballsize scale value reflect_left_x 0 value reflect_right_x : initlimits " dimensions" $call-screen to screenh to screenw - screenw ballsize - pscale * to ball_limit_x - screenh ballsize 2 * - pscale * to ball_limit_hi_y - screenh ballsize batsize + - pscale * to bat_limit_hi_y - screenw ballsize 3 * - pscale * to hit_limit_right_lo_x - screenw ballsize - pscale * to hit_limit_right_hi_x + screenw ballsize - scale to ball_limit_x + screenh ballsize 2 * - scale to ball_limit_hi_y + screenh ballsize batsize + - scale to bat_limit_hi_y + screenw ballsize 3 * - scale to hit_limit_right_lo_x + screenw ballsize - scale to hit_limit_right_hi_x - screenw ballsize 2 * - pscale * to reflect_right_x + screenw ballsize 2 * - scale to reflect_right_x get-msecs to grandseed ; : random1k ( -- n ) grandseed 16807 * 17 + abs to grandseed grandseed 1000 mod ; : unscale ( n -- n ) pscale 2/ + pscale / ; -: calcbatx ( n -- x ) screenw ballsize 3 * - * ballsize + ; +: leftbatx ( -- n ) ballsize ; +: rightbatx ( -- n ) screenw ballsize 2* - ; : paintrect ( c pixx pixy pixw pixh -- ) " fill-rectangle" $call-screen ; \needs xy* : xy* ( x y w h -- x' y' ) rot * >r * r> ; @@ -223,8 +222,8 @@ ballsize 7 * ballsize 2* leftscore drawnumber screenw ballsize 7 * 9 scoresize * + - ballsize 2* rightscore drawnumber - 0 calcbatx leftbaty plotbat - 1 calcbatx rightbaty plotbat + leftbatx leftbaty plotbat + rightbatx rightbaty plotbat ballx bally plotball ; @@ -236,23 +235,23 @@ : resetball ( -- ) 500 to ballstop - screenw ballsize - 2 / pscale * ballx pscale mod + random1k + to ballx - screenh ballsize - 2 / pscale * bally pscale mod + random1k + to bally + screenw ballsize - 2 / scale ballx pscale mod + random1k + to ballx + screenh ballsize - 2 / scale bally pscale mod + random1k + to bally - random1k screenw pscale * * 2000000 / to balldx - random1k screenh pscale * * 2000000 / to balldy - balldx screenw pscale * 3000 / + to balldx - balldy screenh pscale * 6000 / + to balldy + random1k screenw scale * 2000000 / to balldx + random1k screenh scale * 2000000 / to balldy + balldx screenw scale 3000 / + to balldx + balldy screenh scale 6000 / + to balldy random1k 500 < if balldx negate to balldx then random1k 500 < if balldy negate to balldy then ; : initvalues ( -- ) - ballsize 2* pscale * to leftbaty - screenh ballsize 2 * - batsize - pscale * to rightbaty + ballsize 2* scale to leftbaty + screenh ballsize 2* - batsize - scale to rightbaty - screenh pscale * 1000 / to batdy + screenh scale 1000 / to batdy ; : doreset ( -- ) @@ -267,6 +266,54 @@ \ poll key states if you can. [ifdef] olpc +[ifdef] pong-use-touchscreen +0 value pong-ih +: >bat-center ( baty -- centery ) batsize scale 2/ + ; +0 value left-bat-target +0 value right-bat-target +: initkeys ( -- ) + pong-ih 0= if + " /touchscreen" open-dev to pong-ih + then + pong-ih 0= abort" Can't open touchscreen" + + rightbaty >bat-center to right-bat-target + leftbaty >bat-center to left-bat-target + + false to key_esc + false to key_off +; +: restorekeys ( -- ) pong-ih ?dup if close-dev 0 to pong-ih then ; +: scale-xy ( x y -- x' y' ) + swap screenw 1- * d# 15 rshift + swap screenh 1- * d# 15 rshift +; +: scankeys ( -- ) + " get-touch?" pong-ih $call-method if ( x y z down? touch# ) + 3drop ( x y ) + scale-xy ( x' y' ) + scale swap 4 lshift screenw / ( y' 0<=x'<16 ) + dup 1 <= if ( y 0<=x'<16 ) + drop to left-bat-target ( ) + exit + then ( y 0<=x'<16 ) + d# 14 >= if ( y ) + to right-bat-target + exit + then ( y ) + drop ( ) + then + key? if key 27 = if true to key_off else true to key_esc then then +; +\ The "5 >>a" makes the paddles a little sluggish, for more challenge +: left-deltay ( deltat oldy -- oldy deltay ) + nip left-bat-target over >bat-center - 5 >>a +; +: right-deltay ( deltat oldy -- oldy deltay ) + nip right-bat-target over >bat-center - 5 >>a +; +: wait-esc-off false to key_esc ; +[else] \ This works with the FirmWorks pckbd driver. The key map below \ is good for the OLPC keyboard. [ifdef] keyboard-ih @@ -275,6 +322,11 @@ : pong-ih stdin @ ; [then] +0 value key_left_up +0 value key_left_down +0 value key_right_up +0 value key_right_down + : initkeys ." Shift, Hand, Esc, Square" cr d# 3000 ms @@ -314,9 +366,15 @@ then repeat ; +: wait-esc-off ( -- ) begin scankeys key_esc 0= until ; +[then] [else] \ This version uses "key" with normal ASCII. It is typically too slow \ dup to limited keyboard repeat rate. +0 value key_left_up +0 value key_left_down +0 value key_right_up +0 value key_right_down : initkeys ; : restorekeys ; : scankeys @@ -338,6 +396,33 @@ endcase then ; +: wait-esc-off false to key_esc ; +[then] +[ifndef] right-deltay +: left-deltay ( deltat oldy -- oldy deltay ) + 0 ( deltat oldy deltay ) + over bat_limit_lo_y > if ( deltat oldy deltay ) + key_left_up if batdy - then ( deltat oldy deltay' ) + then ( deltat oldy deltay ) + + over bat_limit_hi_y < if ( deltat oldy deltay ) + key_left_down if batdy + then ( deltat oldy deltay ) + then ( deltat oldy deltay ) + + rot * ( oldy deltay' ) \ Scale by the elapsed time +; +: right-deltay ( deltat oldy -- oldy deltay ) + 0 ( deltat oldy deltay ) + + over bat_limit_lo_y > if ( deltat oldy deltay ) + key_right_up if batdy - then ( deltat oldy deltay' ) + then + + over bat_limit_hi_y < if + key_right_down if batdy + then + then + rot * +; [then] : moveball ( oldx oldy newx newy -- ) 2swap eraseball plotball ; @@ -353,7 +438,7 @@ ballx 0< if resetball balldx abs negate to balldx - ballx ballsize 2 * pscale * + to ballx + ballx ballsize 2 * scale + to ballx rightscore 1 + to rightscore rightscore 15 = if -1 to ballstop @@ -362,7 +447,7 @@ ballx ball_limit_x > if resetball balldx abs to balldx - ballx ballsize 2 * pscale * - to ballx + ballx ballsize 2 * scale - to ballx leftscore 1 + to leftscore leftscore 15 = if -1 to ballstop @@ -380,13 +465,13 @@ balldx 0< if ballx hit_limit_left_lo_x hit_limit_left_hi_x between if - bally leftbaty ballsize pscale * - leftbaty batsize pscale * + between if + bally leftbaty ballsize scale - leftbaty batsize scale + between if bally leftbaty < if balldy abs negate to balldy then - bally leftbaty batsize ballsize - pscale * + > if + bally leftbaty batsize ballsize - scale + > if balldy abs to balldy then @@ -406,13 +491,13 @@ balldx 0> if ballx hit_limit_right_lo_x hit_limit_right_hi_x between if - bally rightbaty ballsize pscale * - rightbaty batsize pscale * + between if + bally rightbaty ballsize scale - rightbaty batsize scale + between if bally rightbaty < if balldy abs negate to balldy then - bally rightbaty batsize ballsize - pscale * + > if + bally rightbaty batsize ballsize - scale + > if balldy abs to balldy then @@ -472,8 +557,8 @@ drawcol batx r> batsize + ballsize r> paintrect ; -: movebat ( n oldy newy -- ) - rot calcbatx to batx swap ( newy oldy ) +: movebat ( oldy newy x -- ) + to batx swap ( newy oldy ) over unscale over unscale - ( newy oldy deltay ) dup abs batsize < if ( newy oldy deltay ) dup if ( newy oldy deltay ) @@ -493,36 +578,19 @@ then ; -: updatebats ( deltat -- ) +: updatebats ( deltat -- ) >r - 0 leftbaty 0 ( n oldy deltay ) - - over bat_limit_lo_y > if - key_left_up if batdy - then - then + r@ leftbaty left-deltay ( oldy deltay r: deltat ) - over bat_limit_hi_y < if - key_left_down if batdy + then - then - - r@ * ( n oldy deltay' ) \ Scale by the elapsed time - over + ( n oldy newy ) - dup to leftbaty ( n oldy newy ) - movebat + over + ( oldy newy r: deltat ) + dup to leftbaty ( oldy newy r: deltat ) + leftbatx movebat - 1 rightbaty 0 ( 1 right dy ) + r> rightbaty right-deltay ( oldy deltay ) - over bat_limit_lo_y > if - key_right_up if batdy - then - then - - over bat_limit_hi_y < if - key_right_down if batdy + then - then - - r> * over + - dup to rightbaty - movebat + over + ( oldy newy ) + dup to rightbaty ( oldy newy ) + rightbatx movebat ( ) ; : initeverything ( -- ) @@ -548,25 +616,25 @@ ; : pong ( -- ) - initeverything - begin - get-msecs glastupdate - + initeverything + begin + get-msecs glastupdate - dup 0> if - dup 250 > if - drop - get-msecs to glastupdate - 250 - then - doloop + dup 250 > if + drop + get-msecs to glastupdate + 250 + then + doloop else - drop + drop then - scankeys - key_esc if doreset begin scankeys key_esc 0= until then - key_off until - restorekeys - h# ffff 0 0 screenw screenh paintrect - page + scankeys + key_esc if doreset wait-esc-off then + key_off until + restorekeys + h# ffff 0 0 screenw screenh paintrect + page \ " Count:" type loopcount .d cr \ " Avg millisec:" type totalupdate loopcount / .d cr ;

1 0

[commit] r2165 - cpu/arm dev/video/common
by repository service 03 Feb '11

03 Feb '11

Author: wmb Date: Thu Feb 3 07:58:08 2011 New Revision: 2165 URL: http://tracker.coreboot.org/trac/openfirmware/changeset/2165 Log: ARM / graphics - added bscan, wscan, lscan primitives and used them if present in replace-color. Modified: cpu/arm/kerncode.fth dev/video/common/rectangle16.fth Modified: cpu/arm/kerncode.fth ============================================================================== --- cpu/arm/kerncode.fth Thu Feb 3 07:57:03 2011 (r2164) +++ cpu/arm/kerncode.fth Thu Feb 3 07:58:08 2011 (r2165) @@ -952,6 +952,66 @@ = until c; +\ Find the first occurence of bvalue, returning the residual string +code bscan ( adr len bvalue -- adr' len' ) + ldmia sp!,{r0,r1} \ r0-len r1-adr tos-bvalue + mov r2,tos \ r2-bvalue + movs tos,r0 \ tos-len + psheq r1,sp + nxteq \ Bail out if len=0 + + begin + ldrb r0,[r1],#1 + cmp r0,r2 + deceq r1,#1 + psheq r1,sp + nxteq + decs tos,1 + = until + psh r1,sp +c; + +\ Find the first occurrence of wvalue, returning the residual string +code wscan ( adr len wvalue -- adr' len' ) + ldmia sp!,{r0,r1} \ r0-len r1-adr tos-lvalue + mov r2,tos \ r2-lvalue + movs tos,r0 \ tos-len + psheq r1,sp + nxteq \ Bail out if len=0 + + begin + ldrh r0,[r1],#2 + cmp r0,r2 + deceq r1,#2 + psheq r1,sp + nxteq + decs tos,2 + <= until + psh r1,sp + mov tos,#0 +c; + +\ Find the first occurrence of lvalue, returning the residual string +code lscan ( adr len lvalue -- adr' len' ) + ldmia sp!,{r0,r1} \ r0-len r1-adr tos-lvalue + mov r2,tos \ r2-lvalue + movs tos,r0 \ tos-len + psheq r1,sp + nxteq \ Bail out if len=0 + + begin + ldr r0,[r1],#4 + cmp r0,r2 + deceq r1,#4 + psheq r1,sp + nxteq + decs tos,4 + <= until + psh r1,sp + mov tos,#0 +c; + + \ code /link ( -- /link ) psh tos,sp mov tos,/link c; code /char ( -- 1 ) psh tos,sp mov tos,#1 c; Modified: dev/video/common/rectangle16.fth ============================================================================== --- dev/video/common/rectangle16.fth Thu Feb 3 07:57:03 2011 (r2164) +++ dev/video/common/rectangle16.fth Thu Feb 3 07:58:08 2011 (r2165) @@ -234,17 +234,39 @@ : dimensions ( -- width height ) width height ; : replace-color ( old new -- ) - depth d# 32 = if + depth d# 32 = if ( old new ) swap 565>argb-pixel swap 565>argb-pixel ( old' new' ) - frame-buffer-adr width height * /l* bounds do + frame-buffer-adr width height * /l* ( old new adr len ) +[ifdef] lscan + begin ( old new adr len ) + fourth lscan ( old new adr' len' ) + dup while ( old new adr' len' ) + third third l! ( old new adr len ) + /l /string ( old new adr' len' ) + repeat ( old new adr' len' ) + 4drop ( ) +[else] + bounds do ( old new ) over i l@ xor h# ffffff and 0= if dup i l! then /l +loop 2drop - else - frame-buffer-adr width height * /w* bounds do - over i w@ = if dup i w! then - /w +loop - 2drop +[then] + else ( old new ) + frame-buffer-adr width height * /w* ( old new adr len ) +[ifdef] wscan + begin ( old new adr len ) + fourth wscan ( old new adr' len' ) + dup while ( old new adr' len' ) + third third w! ( old new adr len ) + /w /string ( old new adr' len' ) + repeat ( old new adr' len' ) + 4drop ( ) +[else] + bounds do ( old new ) + over i w@ = if dup i w! then ( old new ) + /w +loop ( old new ) + 2drop ( ) +[then] then ; \ This creates a device method from a termemu method

1 0

[commit] r2164 - dev/usb2/hcd/ohci
by repository service 03 Feb '11

03 Feb '11

Author: wmb Date: Thu Feb 3 07:57:03 2011 New Revision: 2164 URL: http://tracker.coreboot.org/trac/openfirmware/changeset/2164 Log: USB - fixed OHCI breakage from recent probing rewrite. Modified: dev/usb2/hcd/ohci/ohci.fth dev/usb2/hcd/ohci/probe.fth Modified: dev/usb2/hcd/ohci/ohci.fth ============================================================================== --- dev/usb2/hcd/ohci/ohci.fth Thu Feb 3 02:00:58 2011 (r2163) +++ dev/usb2/hcd/ohci/ohci.fth Thu Feb 3 07:57:03 2011 (r2164) @@ -58,6 +58,19 @@ : hc-cntl-clr ( bit-mask -- ) hc-cntl@ swap invert and hc-cntl! ; : hc-cntl-set ( bit-mask -- ) hc-cntl@ swap or hc-cntl! ; +: reset-port ( port -- ) + >r + h# 1.0002 r@ hc-rh-psta! \ enable port + h# 10 r@ hc-rh-psta! \ reset port + r@ d# 10 0 do + d# 10 ms + dup hc-rh-psta@ 10.0000 and ?leave + loop drop + r@ hc-rh-psta@ 10.0000 and 0= if abort then + h# 1f.0000 r> hc-rh-psta! \ clear status change bits + d# 256 ms +; + : reset-usb ( -- ) ohci-reg dup 0= if map-regs then 1 hc-rh-stat! \ power-off root hub @@ -65,6 +78,7 @@ d# 10 ms 0= if unmap-regs then ; + : init-ohci-regs ( -- ) hcca-phys hc-hcca! \ physical address of hcca Modified: dev/usb2/hcd/ohci/probe.fth ============================================================================== --- dev/usb2/hcd/ohci/probe.fth Thu Feb 3 02:00:58 2011 (r2163) +++ dev/usb2/hcd/ohci/probe.fth Thu Feb 3 07:57:03 2011 (r2164) @@ -4,19 +4,6 @@ hex headers -: reset-port ( port -- ) - >r - h# 1.0002 r@ hc-rh-psta! \ enable port - 10 r@ hc-rh-psta! \ reset port - r@ d# 10 0 do - d# 10 ms - dup hc-rh-psta@ 10.0000 and ?leave - loop drop - r@ hc-rh-psta@ 10.0000 and 0= if abort then - h# 1f.0000 r> hc-rh-psta! \ clear status change bits - 100 ms -; - : probe-root-hub-port ( port -- ) dup hc-rh-psta@ 1 and 0= if drop exit then ( port ) \ No device connected

1 0

[commit] r2163 - cpu/arm/olpc/1.75
by repository service 03 Feb '11

03 Feb '11

Author: wmb Date: Thu Feb 3 02:00:58 2011 New Revision: 2163 URL: http://tracker.coreboot.org/trac/openfirmware/changeset/2163 Log: OLPC XO-1.75 - include the touchscreen driver in the build. Modified: cpu/arm/olpc/1.75/fw.bth Modified: cpu/arm/olpc/1.75/fw.bth ============================================================================== --- cpu/arm/olpc/1.75/fw.bth Thu Feb 3 02:00:19 2011 (r2162) +++ cpu/arm/olpc/1.75/fw.bth Thu Feb 3 02:00:58 2011 (r2163) @@ -162,6 +162,7 @@ fload ${BP}/dev/olpc/touchpad/syntpad.fth \ Touchpad diagnostic fload ${BP}/cpu/x86/pc/olpc/gridmap.fth \ Gridded display tools fload ${BP}/cpu/x86/pc/olpc/via/copynand.fth +fload ${BP}/cpu/arm/olpc/1.75/exc7200-touchscreen.fth \ Touchscreen driver and diagnostic fload ${BP}/cpu/arm/mmp2/keypad.fth [ifndef] cl2-a1

1 0

Jump to page:

2025

2024

2023

2022

2021

2020

2019

2018

2017

2016

2015

2014

2013

2012

2011

2010

2009

2008

openfirmware