Change in coreboot[master]: intel/bd82x6x: Add GBE ACPI device

[Tobias Diedrich (Code Review)]

Tobias Diedrich has uploaded this change for review. ( https://review.coreboot.org/22807

Change subject: intel/bd82x6x: Add GBE ACPI device
......................................................................

intel/bd82x6x: Add GBE ACPI device

Tested on Intel NUC DCP847SKE:
systemd default network interface name changes from enp0s25 to eno1,
which matches the Intel BIOS (though there it is due to SMBIOS data).

Change-Id: I02613169498eed3d6d9ea5963ea3c2c08a40ef99
Signed-off-by: Tobias Diedrich 
---
A src/southbridge/intel/bd82x6x/acpi/gbe.asl
M src/southbridge/intel/bd82x6x/acpi/pch.asl
2 files changed, 63 insertions(+), 0 deletions(-)

git pull ssh://review.coreboot.org:29418/coreboot refs/changes/07/22807/1

diff --git a/src/southbridge/intel/bd82x6x/acpi/gbe.asl b/src/southbridge/intel/bd82x6x/acpi/gbe.asl
new file mode 100644
index 0000000..09a8318
--- /dev/null
+++ b/src/southbridge/intel/bd82x6x/acpi/gbe.asl
@@ -0,0 +1,60 @@
+/*
+ * This file is part of the coreboot project.
+ *
+ * Copyright (C) 2017 Tobias Diedrich 
+ *
+ * This program is free software; you can redistribute it and/or
+ * modify it under the terms of the GNU General Public License as
+ * published by the Free Software Foundation; version 2 of
+ * the License.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ */
+
+/* Intel PCH Gigabit Ethernet 0:19.0 */
+
+Device (GLAN)
+{
+	Name (_ADR, 0x00190000)
+
+	// Power Resources for Wake
+	Name (_PRW, Package(){
+		13,  // Bit 13 of GPE
+		 4   // Can wake from S4 state.
+	})
+
+	/*
+	 * Device Specific Method
+	 * Arg0 - UUID
+	 * Arg1 - Revision
+	 * Arg2 - Function Index
+	 * Arg3 - Function Arg
+	 */
+	Method (_DSM, 4, Serialized)  // _DSM: Device-Specific Method
+	{
+		// Device label GUID, used by systemd for naming.
+		If (Arg0 == ToUUID ("E5C937D0-3553-4D7A-9117-EA4D19C3434D"))
+		{
+			Switch (ToInteger(Arg2)) {
+				// Function 0 (Report supported functions)
+				Case (0) {
+					// Supports functions 7 & 0
+					Return (Buffer() { 0x81 })
+				}
+				// Function 7 (DEVICE_LABEL_DSM)
+				Case (7) {
+					Return (Package(){
+						1, // Instance number
+						"LAN",  // Optional name
+					})
+				}
+			}
+		}
+
+		// No functions supported for the given GUID
+		Return (Buffer() { 0 })
+	}
+}
diff --git a/src/southbridge/intel/bd82x6x/acpi/pch.asl b/src/southbridge/intel/bd82x6x/acpi/pch.asl
index cfa27d2..7d8d5df 100644
--- a/src/southbridge/intel/bd82x6x/acpi/pch.asl
+++ b/src/southbridge/intel/bd82x6x/acpi/pch.asl
@@ -234,6 +234,9 @@
    }
 }

+// Gigabit Ethernet 0:19.0
+#include "gbe.asl"
+
 // High Definition Audio (Azalia) 0:1b.0
 #include "audio.asl"